HP-67/97 Pinball Wizard Game

Back to main page If this is useful to you, Email me at: Genewright143@hotmail.com


This program will duplicate the play of a standard pinball machine, with out hole bonus points, SPECIAL for higher scoring, two thumper, (mushroom or jet) bumpers, a spinner gate, 3 drop targets for a free ball, bonus advance roll overs, kick out holes, 2 flippers and even the option to tilt the machine with a 2 out of 3 chance of putting the ball back in play. The program is running constantly with input occuring during the HP-67/97's pause input feature.

This program was developed and first published by Craig Pearce in the January 1977 65 Notes (later PPC Journal) V4N1 page 4 and program listing on page 15.

There are eight different scoring devices on the playing field. The device number is shown to the right of the decimal point on the calculator display during play. The number to the left of the decimal point is the score just made on that device. So a 500.5 would mean 500 points from device #5.


Here's a description of each device

Device 1. This consists of two "star" roll overs which, when hit, will add 10 points to the player's score and switch on the "SPECIAL", indicated by all the zeros shown after the device number in the display. When this occurs, all devices listed below will score ten times higher than normal! Hitting devices #1 repeatedly will turn the SPECIAL on and off.

Device 2. This consists of two top roll over channels which score either 100 or 1000 points (depending on whether SPECIAL is lit) and advance the player's out hole bonus by 1000 points.

Device 3. These are two thumper, mushroom or jet bumpers (called different names by different pinball machine manufacturers). Each score 100 or 1000 points when hit (depending on whether SPECIAL is lit). The ball can bounce between them from 1 to 10 times, so the score on device #3 will differ from one time to the next.

Device 4. This is a spinner gate, which will score 50 or 500 points (depending on whether SPECIAL is lit). The gate will spin from 1 to 25 revolutions and the score will be different each time device 4 is hit.

Device 5. These consist of two kick out holes, where the ball will drop in and be kicked back out, scoring 50 or 500 (depending on whether SPECIAL is lit).

Device 6. These are two bonus advance roll over stars, and function the same as device #2.

Device 7. This consists of 3 drop targets. Each time device 7 is hit, 1 target drops away, and scores an immediate 10 points for the player. When the third target is hit (device 7 comes up for the third time that ball), all the targets are reset, the player scores 100 or 1000 (depending on whether SPECIAL is lit), and another ball is added to the ones left for the player to play. Each time all three targets are struck, the same action occurs.

Device 8. These consist of simple sling-shot kickers, and only score 10 points each when hit.

How to play. Initialize the game by inputing a decimal seed 0 < seed < 1, and pressing RTN R/S. The display will flash "0". Obtain a credit of 2 games by pressing A (and spend a quarter). Start the first game by pressing "B". A 1 will be displayed/printed and 5 will be flashed on the display, indicating that there are 5 balls to be played. To shoot the first ball, press the decimal button.

The game will start and numbers will be flashed on the display indicating which devices are hit and the resulting points scored.

If a -1 or -3 are displayed, this is the signal that you need to either hit the left flipper (by typing in a 1) or the right flipper (by typing in a 3). You must do this quickly or the ball will roll down the out hole. If you see a -2 in the display, this means the ball is headed down the out hole and cannot be influenced by a flipper. You can try to tilt the machine to keep the ball in play by pressing a "2". However, this will only work about 2/3 of the time. If you "tilt" the machine, all bonus points are lost and you go to the next ball.

If the ball goes down the out hole, the display will show the tally of the bonus being added to your score by adding 1000 for each bonus you received. If SPECIAL is on when the ball rolls out, this bonus is doubled.

If you see a "0" after shooting a ball with no points previously scored, the ball is returned to you to shoot again.

Note: at the start of each new ball, the drop targets are reset, the out bonus is reset to 1000, and SPECIAL is switched off.

A score of 50,000 or greater will provide the user with a free game.


Program Notes: RDN is Roll Down, X NE Y? or X NE 0? is X not equal to Y or 0, as the case may be. Remember, the HP-67/97 made a distinction between the lower case i and the upper case I. The listing is correct where I have used the lower case letter.

Program Listing!

Line      Instruction
01         FRC
02         PI
03         X<>Y
04         X=0?
05         +
06         FRC
07         STO E
08         5
09         0
10         STO B
11         1
12         0
13         STO A
14         X^2
15         STO C
16         CLX
17         STO 0
18         STO 1
19         STO 2
20         GTO a
21         LBL e
22         RCL E
23         9
24         9
25         7
26         *
27         FRC
28         STO E
29         RTN
30         LBL A
31         2
32         ST+ 1
33         .
34         2
35         5
36         ST- 2
37         RCL 1
38         PRTX
39         LBL a
40         2
41         CHS
42         STO I
43         RCL 0
44         5
45         EEX
46         4
47         /
48         INT
49         ST+ 1
50         RCL 0
51         PSE
52         GTO i
53         LBL C
54         DSP 2
55         RCL 2
56         PSE
57         RDN
58         DSP 0
59         RTN
60         LBL B
61         RCL 1
62         X=0?
63         GTO a
64         1
65         ST- 1
66         -
67         PRTX
68         0
69         STO 0
70         5
71         STO 3
72         LBL b
73         CF 0
74         DSP 0
75         3
76         STO 7
77         EEX
78         3
79         STO 6
80         LBL c
81         CF 3
82         RCL 3
83         X=0?
84         GTO a
85         PSE
86         F3?
87         F3?
88         GTO c
89         1
90         ST- 3
91         DSP 1
92         X<>Y
93         LBL d
94         GSB e
95         1
96         2
97         *
98         INT
99         3
100        -
101        X=Y?
102        GTO d
103        X>0?
104        GTO E
105        PSE
106        X=0?
107        GTO 0
108        F3?
109        F3?
110        GTO 0
111        CHS
112        X NE Y?
113        GTO 0
114        2
115        CHS
116        X NE Y?
117        GTO d
118        GSB e
119        3
120        *
121        INT
122        X=0?
123        GTO b
124        GTO d
125        LBL E
126        STO I
127        GTO i
128        LBL 0
129        8
130        CHS
131        STO I
132        RCL 0
133        X NE 0?
134        GTO 0
135        1
136        ST+ 3
137        DSP 0
138        GTO c
139        LBL 0
140        1
141        F0?
142        2
143        ST* 6
144        RCL 0
145        PSE
146        EEX
147        3
148        ST- 6
149        ST+ 0
150        RCL 0
151        PSE
152        RCL 6
153        X NE 0?
154        GTO i
155        RDN
156        PSE
157        GTO b
158        LBL 9
159        F0?
160        RCL A
161        F0?
162        *
163        LBL D
164        ST+ 0
165        RCL I
166        RCL A
167        /
168        +
169        PSE
170        PSE
171        GTO d
172        LBL 1
173        F0?
174        GTO 1
175        SF 0
176        DSP 9
177        RCL A
178        GTO D
179        LBL 1
180        DSP 1
181        CF 0
182        RCL A
183        GTO D
184        LBL 3
185        RCL C
186        RCL A
187        GTO 3
188        LBL 4
189        RCL B
190        2
191        5
192        LBL 3
193        GSB e
194        *
195        1
196        +
197        INT
198        *
199        GTO 9
200        LBL 5
201        RCL B
202        GTO 9
203        LBL 2
204        LBL 6
205        EEX
206        3
207        ST+ 6
208        RCL C
209        GTO 9
210        LBL 7
211        RCL A
212        DSZ i
213        GTO 9
214        3
215        STO 7
216        1
217        ST+ 3
218        RCL C
219        GTO 9
220        LBL 8
221        RCL A
222        GTO D

Visitors since 5/10/97