CONCENTRATION Game for the HP-25/25C
Back to main page If this is useful to you, Email me at: Genewright143@hotmail.com
Here's a cute little game for that dusty old HP-25 or HP-25C you have lying around.

It's based on the idea of the game SIMON. A series of numbers of increasing length is flashed on the screen and you are asked to key it in to test your memory skill.

There's a twist added as well. You can start with a number of 1 digit which is flashed 1 time before you are asked to key it back in. Then you get two 2 digit numbers, the first of which is flashed two times before you key it in, but the second one is only flashed once. So by the time you make it up to 9 digit numbers (You can remember that many, can't you?), the first 9 digit number is flashed 9 times, but the ninth 9 digit number will only be flashed once. Fun.

Here's the instructions followed by the game itself.

1) Make sure you're in RUN mode, not PRGM. ;-)

2) Key a decimal seed, Press ENTER, enter the starting digit length (1 for 1 digit number, 4 for a four digit number, etc.)

3) Press f prgm (similar to a RTN or GTO 00), and then press R/S.

4) When the program stops, the display will show the integer length as the exponent and the number of times the mystery number will be flashed as the mantissa.

5) Press R/S.

6) A random number will be flashed. When the display shows zero, key in the number that was flashed. If you are correct, the integer length will be stay the same as in step 4, but the number of flashes will be decreased. If you are incorrect, the number of flashes and the integer length will stay the same, to help you practice your short-term memory.

(Lines 9 and 18 are multiply, line 13 is inverse tangent, Line 26 is an instruction that clears the stack, Line 27 is a sigma minus, line 28 is X not equal to zero, line 32 is X not equal to Y. Throughout the listing, the little f's and g's represent the yellow and blue prefix keys that are pressed to put a certain instruction into the program.)

Program Listing

```01   X<>Y
02   STO 0
03   X<>Y
04   STO 4
05   STO 7
06   RCL 4
07   RCL 7
08   g 10^X
09   X
10   f SCI 0
11   R/S
12   RCL 0
13   g TAN-1
14   g FRAC
15   STO 0
16   RCL 7
17   g 10^X
18   X
19   f INT
20   STO 1
21   RCL 4
22   STO 3
23   f FIX 0
24   RCL 1
25   f PAUSE
26   f STK
27   f SIGMA-
28   g X NE 0
29   GTO 24
30   R/S
31   RCL 1
32   f X NE Y
33   GTO 06
34   RCL 4
35   1
36   STO - 4
37   f X NE Y
38   GTO 06
39   RCL 7
40   +
41   GTO 04
```